Pipe Bombs Mutator. Мутатор взрыв взрывчатки при смерти

JustRage
No Grade Newbie
Аватара пользователя
Сообщения: 25
Зарегистрирован: 30 май 2012, 20:46

27 ноя 2014, 22:47

Код: Выделить всё

Class PipeBombsMut extends Mutator;

function PostBeginPlay()
{
   local PBGameRules pbRules;
   if( pbRules==None )
      pbRules = Spawn(Class'PBGameRules');
   Super.PostBeginPlay();
}

defaultproperties
{
   GroupName="KF-CleanMap"
   FriendlyName="PipeBombsMut"
   Description="Destroys pipebombs after player death"
   bAddToServerPackages=True
}

Код: Выделить всё

class PBGameRules extends GameRules;

function PostBeginPlay()
{
   if( Level.Game.GameRulesModifiers==None )
      Level.Game.GameRulesModifiers = Self;
   else Level.Game.GameRulesModifiers.AddGameRules(Self);
}

function AddGameRules(GameRules GR)
{
   if ( GR!=Self )
      Super.AddGameRules(GR);
}

function ScoreKill (Controller killer , Controller killed)
{
   local PipeBombProjectile pb;
   if(killed.IsA('PlayerController'))
   {
      foreach DynamicActors(class'PipeBombProjectile',pb)
      {
         if   (
               pb.Instigator!=None &&
               pb.Instigator.Controller!=None &&
               pb.Instigator.Controller==killed
            )
         {
            pb.Explode(pb.Location,vect(0,0,0));
         }
      }
   }
   if (nextGameRules != none)
      nextGameRules.scoreKill (killer , killed);
}

Автор: Flame
Код для мутатора: PipeBombsMut.PipeBombsMut
Скомпилированная версия: https://yadi.sk/d/eQf_FqP_cjCFX

Nurull
No Grade Newbie
Аватара пользователя
Сообщения: 9
Зарегистрирован: 16 авг 2011, 01:36

27 ноя 2014, 23:06

спс


Вернуться в «Мутаторы»

Кто сейчас на конференции

Сейчас этот форум просматривают: нет зарегистрированных пользователей и 1 гость